Option Explicit
            
Private WithEvents oGrid As CtrlGrid
            
Private Sub Form_Load() ' UserForm_Initialize pour Excel
Set oGrid = CreateTGLControl(CtrlGrid, Me.subFormGrid)
End Sub

Option Compare Database
Option Explicit
            
' Objet Grille
Private WithEvents oGrid As CtrlGrid
            
Private Sub Form_Load()
' Initialise l'objet
Set oGrid = CreateTGLControl(CtrlGrid, Me.subFormGrid)
' Affiche les en-têtes
oGrid.ColumnHeader = True
' Source de données
oGrid.RowSource = "select false as sel,* from TGridTable"
' Ajout d'une colonne de sélection (checkbox) avec le champ sel en source
With oGrid.ColumnByName("sel")
        .TypeColumn = TGLColumnTypeCheckBox
        .AllowResize = False
        .Caption = ""
        .DisplayVertLine = False
End With
' Champ notation
oGrid.ColumnByName("note").TypeColumn = TGLColumnTypeRating
' Champ progression
oGrid.ColumnByName("progression").TypeColumn = TGLColumnTypeProgress
oGrid.ColumnByName("progression").DisplayProgressPercent = True
' Champ Valide (case à cocher)
oGrid.ColumnByName("valide").Width = -1
oGrid.ColumnByName("valide").HorzAlign = TGLAlignHorzCenter
' Date validité en gras
oGrid.ColumnByName("datevalid").Bold = True
' Nom en italique
oGrid.ColumnByName("nom").Italic = True
' Exécute la requête et rempli la grille
oGrid.Requery
' Colonnes auto-redimensionnées
oGrid.AutoSize
' En-têtes auto-redimensionnés
oGrid.HeaderAutoSize
' Redimensionne la colonne de notation
oGrid.ColumnByName("note").Width = 80
' Ajout d'un bouton dans la dernière colonne
With oGrid.ColumnAdd("Button", TGLColumnTypeImage)
    .Width = 60
    .AllowResize = False
    .MouseCursor = IDC_HAND
    .ConstantValue = "monbouton"
End With
' Couleur de fond
oGrid.BackColor = RGB(230, 230, 255)
' Couleur de sélection (aucune couleur)
oGrid.SelectionColor = -1
' Sélection multiple acceptée (touche CTRL)
oGrid.MultipleSelection = True
' Les deux premières colonnes sont fixes
oGrid.FixedColumns = 2
' Ajout de l'image du bouton à partir d'une image de menu
' Référence "Microsoft Office XX Object Library" requise
Dim o As CommandBarControl
oGrid.ImageListAddFromPicture "monbouton", CommandBars("Database").Controls(1).Picture, _
        CommandBars("Database").Controls(1).Mask
' Hauteur des lignes
oGrid.RowHeight = 40
' Dessine la grille
oGrid.Refresh
End Sub
            
'Avant affichage d'un cellule
Private Sub oGrid_BeforeDrawCell(pRow As CtrlGridRowBeforeDraw, pColonne As CtrlGridColumnBeforeDraw)
Select Case pColonne.Name
    Case "nb" ' Nombre à afficher en rouge ou vert
        If pRow.Value(pColonne.Name) < 300 Then pColonne.FillColor = vbRed Else pColonne.FillColor = vbGreen
    Case "sel" ' Case coché si ligne sélectionnée
        pRow.Value("sel") = pRow.Selected
End Select
End Sub
            
' Sur click souris
Private Sub oGrid_MouseDown(pRow As CtrlGridRow, pCol As CtrlGridColumn, Button As Integer, Shift As Integer, X As Single, Y As Single)
If Not pCol Is Nothing Then
    If pCol.Name = "Button" Then
        ' Si click sur bouton => affiche un message avec le nom de la ligne cliquée
        MsgBox pRow.Value("Nom")
    End If
End If
End Sub