VBA et développement Web

Vous avez sans doute déjà vu des adresses de cette forme :

http://monURL/index.php?data1=valeur1&data2=valeur2

Cela signifie que nous passons deux valeurs à la page :
- data1=valeur1
- data2=valeur2

Écrivons un fichier php1.php contenant ce code :

<?php
// Lecture des variables
$data1 = $_POST['data1'];
$data2 = $_POST['data2'];
// Écriture des variables
echo "$data1\n";
echo "$data2\n";
?>

Comme c'est notre premier code php, nous allons le décortiquer.

D'abord le code php est inséré entre les balises <?php et ?>.
Ensuite on récupère les données avec l'instruction $_POST.
On écrit enfin chaque donnée avec l'instruction echo.
Petite subtilité de php : on peut inclure une variable dans une chaîne de caractères.
Le \n est un retour à la ligne.

Une écriture différente du echo pourrait utiliser l'opérateur de concaténation qui est le point en php :

echo $data1."\n";

Placez ce fichier sur un serveur php.
Pour déposer un fichier sur un serveur, vous pouvez utiliser par exemple FileZilla
J'ai déposé ce fichier ici : https://arkham46.developpez.com/articles/office/officeweb/fichiersphp/php1.php.

Appelons ce fichier avec une requête HTTP :

Function SendPhp1()
Dim oWinHTTP As WinHTTP.WinHttpRequest
Set oWinHTTP = New WinHTTP.WinHttpRequest
oWinHTTP.Open "POST", "http://arkham46.developpez.com/articles/office/officeweb/fichiersphp/php1.php", False
oWinHTTP.setRequestHeader "Content-Type", "application/x-www-form-urlencoded"
oWinHTTP.send "data1=valeur1&data2=valeur2"
Debug.Print oWinHTTP.responseText
End Function

Si besoin, paramétrez votre proxy comme vu au paragraphe VI-A.

On ouvre toujours une connexion avec open, et on envoie la requête avec send.
Entre les deux, une instruction setRequestHeader a fait son apparition.
On indique avec "application/x-www-form-urlencoded" que l'on va passer des paramètres.
Ces paramètres sont indiqués dans la commande send.
Chacun des paramètres est séparé par un &.

On affiche enfin la réponse du serveur contenue dans responseText.
Cette réponse est ce que nous écrivons en php avec echo.

Exécutez la fonction SendPhp1, le résultat s'affiche dans la fenêtre exécution.

valeur1
valeur2

Peu utile en l'état, le code php peut facilement être modifié pour par exemple écrire un fichier contenant les données, ou les inscrire dans une base de données MySQL par exemple.

Pour finir, on peut essayer d'envoyer des données issues de variables.
On va également insérer un saut de ligne dans une des variables pour tester si ça passe.

Function SendPhp1()
Dim oWinHTTP As WinHTTP.WinHttpRequest
Dim sData1 As String
Dim sData2 As String
Set oWinHTTP = New WinHTTP.WinHttpRequest
oWinHTTP.Open "POST", "http://arkham46.developpez.com/articles/office/officeweb/fichiersphp/php1.php", False
oWinHTTP.setRequestHeader "Content-Type", "application/x-www-form-urlencoded"
sData1 = "Test" & vbCrLf & "sur 2 lignes"
sData2 = "1 ligne"
oWinHTTP.send "data1=" & sData1 & "&data2=" & sData2
Debug.Print oWinHTTP.responseText
End Function

On a ajouté deux variables sData1 et sData2 qui contiennent du texte.
La variable sData1 contient un saut de ligne (vbcrlf).
On doit alors construire une chaîne de caractères pour insérer nos variables et envoyer le tout avec send.
Exécutez la fonction SendPhp1, le résultat s'affiche dans la fenêtre exécution.

Test
sur 2 lignes
1 ligne

Pas de souci donc pour insérer un saut de ligne.

Essayons à présent de mettre des caractères accentués, dans sData1 par exemple :

sData1 = "Test de caractères accentués"

Le résultat n'est pas correct :

Test de caract�res accentués
1 ligne

Il faut dire qu'on n'a rien précisé quant au contenu de la reponse.
Dans le fichier php il faut ajouter un en-tête, juste après le <?php :

<?php
header('Content-Type: text/plain; charset=UTF-8');
[...]

On indique ainsi qu'on retourne un fichier texte brut (text/plain) avec un encodage UTF-8 qui gère correctement les accents.

Les valeurs possibles de la valeur de Content-Type sont listées ici : MIME Media Types.


Autre souci possible : mettre des guillemets dans une variable :

sData1 = "Test de ""guillemets"""

Le résultat peut ne pas être correct non plus :

Test de \"guillemets\"
1 ligne

En fonction de l'installation de php, celui-ci peut éventuellement ajouter des caractères d'échappement (\).
Pour les retirer, utilisez en php la fonction stripslashes sur les variables reçues.

<?php
header('Content-Type: text/plain; charset=UTF-8');
// Lecture des variables
$data1 = $_POST['data1'];
$data2 = $_POST['data2'];
if(get_magic_quotes_gpc()) // Si les magic quotes sont activés
{
    $data1 = stripslashes($data1);
    $data2 = stripslashes($data2);
 }
// Écriture des variables
echo "$data1\n";
echo "$data2\n";
?>

Reste un problème si vous souhaitez utiliser un caractère & dans une variable.
Comme c'est un caractère réservé pour la séparation des données, on ne peut pas l'utiliser dans une des valeurs.

Plutôt que de passer tous les paramètres sur une même ligne, on peut passer des données structurées.
Il faut utiliser un type de contenu : "multipart/form-data".

Il est alors possible d'envoyer des données de type complexe.
Les valeurs possibles du type de donnée (Content-Type) sont listées ici : MIME Media Types.

On crée une nouvelle fonction SendPhp2 qui est assez proche de la précédente :

Function SendPhp2()
Dim oWinHTTP As WinHTTP.WinHttpRequest
Dim sData1 As String
Dim sData2 As String
Dim sFormData As String
Const csBoundary As String = "A@poXX125"
Set oWinHTTP = New WinHTTP.WinHttpRequest
oWinHTTP.Open "POST", "http://arkham46.developpez.com/articles/office/officeweb/fichiersphp/php1.php", False
oWinHTTP.setRequestHeader "Content-Type", "multipart/form-data; charset=""UTF-8"";boundary=" + csBoundary
sData1 = "Test de ""guillemets"""
sData2 = "caractères spéciaux <$£^??çço ©"
sFormData = ???
oWinHTTP.send sFormData
Debug.Print oWinHTTP.responseText
End Function

Comme toujours on ouvre d'abord une connexion avec open.
On cible pour cet exemple le même fichier php que pour le chapitre précédent.

Le Content-Type de la méthode setRequestHeader a changé, c'est maintenant : multipart/form-data.
On a ajouté également (séparé par un point-virgule) le type de caractères utilisé : UTF-8.
Si on ne précise pas UTF-8, les caractères accentués ne passeront pas.
Il faut ensuite définir une chaîne de séparation des données, appelée boundary.
Cette valeur est arbitraire : il faut juste s'assurer que cette chaîne de caractères n'apparaît pas dans les données.

Ensuite il faut envoyer nos données que nous allons écrire dans la variable texte sFormData.
Ces données doivent être écrites selon un format très précis : W3C Recommendation.

Pour les données que l'on souhaite envoyer, voici ce que doit contenir sFormData :

--A@poXX125
Content-Disposition: form-data; name="data1"
Content-Type: text/plain

Test de "guillemets"
--A@poXX125
Content-Disposition: form-data; name="data2"
Content-Type: text/plain

caractères spéciaux <$£^??çço ©
--A@poXX125--

Chaque valeur commence par la valeur de boundary définie en en-tête de la requête, précédée de deux tirets.
Pour chacune de ces valeurs, il faut définir la disposition (form-data) et le nom de la variable qui sera récupérée en php.
Puis vient le type de contenu, optionnel car text/plain par défaut.
On peut utiliser tout type MIME connu, pourvu qu'on sache le gérer à l'arrivée sur le serveur.

Attention, il faut ensuite un saut de ligne (vbCrLf) avant de mettre le contenu de la donnée.
La fin de la donnée est marquée par une nouvelle valeur boundary précédée par deux tirets.
Ce qui marque en fait le début de la donnée suivante.

Pour la dernière donnée, on marque la fin en ajoutant deux tirets (donc deux tirets avant la boundary et deux tirets après).

On peut facilement écrire ces données dans une variable :

sFormData = "--" & csBoundary & vbCrLf & _
       "Content-Disposition: form-data; name=""data1""" & vbCrLf & _
       "Content-Type: text/plain" & vbCrLf & _
       vbCrLf & _
       sData1 & vbCrLf & _
       "--" & csBoundary & vbCrLf & _
       "Content-Disposition: form-data; name=""data2""" & vbCrLf & _
       "Content-Type: text/plain" & vbCrLf & _
       vbCrLf & _
       sData2 & vbCrLf & _
       "--" & csBoundary & "--"

Le serveur nous renvoie nos valeurs (par les echo du php) :

Test de "guillemets"
caractères spéciaux <$£^??çço ©

À noter :
- pas de souci avec cette méthode si la valeur contient un caractère & par exemple ;
- il est toujours indispensable de retirer les slashes avec stripslashes comme vu au chapitre précédent.

Pour une utilisation un peu plus poussée de cette méthode, voir les deux chapitres suivants.

Permettre l'envoi d'un fichier au serveur n'est pas sans danger.
Une personne mal intentionnée pourrait envoyer sur votre serveur un fichier contenant du code malveillant.
Il convient donc de prendre certaines précautions.
Voici une page très intéressante sur ce sujet : Secure File Upload Check List With PHP.

Pour des raisons évidentes, je n'ai pas placé le fichier php d'upload sur mon serveur.
Pour tester le code qui suit, vous devrez placer le fichier sur votre serveur php et modifier son adresse dans le code VBA.

Envoyer un fichier sur le serveur avec php peut s'avérer très utile.
Pas besoin d'un accès FTP avec les codes d'accès, il suffit d'un accès à la page php, et un accès en écriture par php sur le répertoire voulu.
Il faudra tout de même faire quelques vérifications pour ne pas laisser l'utilisateur uploader n'importe quoi !

Pour plus d'informations sur l'upload de fichier en php, voici un article très intéressant dont nous allons nous inspirer : Upload de fichiers en PHP.

Cet article explique la création d'un formulaire HTML et le code PHP qui se charge de l'upload.
Notre travail ici sera principalement de remplacer le formulaire HTML par du code VBA.

Pour envoyer un fichier, il faut utiliser un type de contenu "multipart/form-data" comme vu au chapitre précédent :

Function SendFilePhp()
Dim oWinHTTP As WinHTTP.WinHttpRequest
Dim sFormData As String
Const csBoundary As String = "A@poXX125"
Set oWinHTTP = New WinHTTP.WinHttpRequest
oWinHTTP.Open "POST", "http://arkham46.developpez.com/articles/office/officeweb/fichiersphp/phpupload.php", False
oWinHTTP.setRequestHeader "Content-Type", "multipart/form-data; charset=""UTF-8"";boundary=" + csBoundary
sFormData = ???
oWinHTTP.send sFormData
Debug.Print oWinHTTP.responseText
End Function

Le code php est écrit dans un fichier phpupload.php.
Pour commencer, nous allons ajouter une seule ligne dans ce fichier.

<?php print_r($_FILES); ?>

Cette ligne écrit les propriétés des fichiers envoyés.
Cela ne suffit pas à gérer l'upload complet, nous écrirons plus tard la suite du code php.

Reste à remplir le plus gros morceau du code VBA : les données dans sFormData.
Voici la structure de ces données :

--A@poXX125
Content-Disposition: form-data; name="fichier1"; filename="monfichier.ext"
Content-Type: application/octet-stream

... contenu du fichier ...
--A@poXX125--

Ces données doivent être écrites selon un format très précis : W3C Recommendation.

On retrouve la valeur boundary qui délimite les données.

Le nom de notre variable est "fichier1".
On lui précise un nom de fichier avec l'attribut filename.
C'est cet attribut filename qui distingue un upload de fichier d'un simple envoi de données.

Le type de contenu est application/octet-stream, c'est-à-dire un contenu binaire.
Si on connaît le type de contenu envoyé, on peut le préciser ici : par exemple image/gif.

Ensuite vient le contenu du fichier, car le chemin donné dans filename n'est qu'une information et ne demande pas la lecture du contenu du fichier.
Et c'est ici que ça se complique.
On souhaite envoyer un contenu binaire, c'est-à-dire le contenu brut du fichier.
Passer par une variable texte (as String) risque de ne pas conserver ces données à l'état brut.
Nous allons donc utiliser un tableau d'octets :

Function SendFilePhp()
Dim oWinHTTP As WinHTTP.WinHttpRequest
Dim sFormData() As Byte
Dim sFormDataHeader As Variant
Dim sFormDataFile As Variant
Dim sFormDataFooter As Variant
Const csBoundary As String = "A@poXX125"
Const sFileName As String = "C:\monimage.jpg"
Set oWinHTTP = New WinHTTP.WinHttpRequest
oWinHTTP.Open "POST", "http://arkham46.developpez.com/articles/office/officeweb/fichiersphp/phpupload.php", False
oWinHTTP.setRequestHeader "Content-Type", "multipart/form-data; charset=""UTF-8"";boundary=" + csBoundary
sFormData = ???
oWinHTTP.send sFormData
Debug.Print oWinHTTP.responseText
End Function

Le contenu final que nous enverrons au serveur (sFormData) est un tableau (car on a mis des parenthèses).
Il est dynamique, c'est-à-dire qu'on n'a pas indiqué sa taille.
Et il contient des éléments de type Byte (Octet), c'est le plus petit élément disponible en VB.

On a également déclaré trois variables :
- sFormDataHeader : contiendra le contenu avant les données du fichier ;
- sFormDataFile : contiendra le contenu du fichier ;
- sFormDataFooter : contiendra le contenu après les données du fichier.

sFormDataHeader et sFormDataFooter seront des chaînes de caractères.
sFormDataFile sera un tableau d'octets.
Ces trois variables sont déclarées de type Variant, cela nous permettra de les concaténer.

Notez aussi l'ajout d'une constante sFileName qui contient le nom du fichier du PC à uploader.
Nous nous contentons ici d'une simple constante.
Il est toutefois possible d'ouvrir une boîte de dialogue de recherche de fichier :
- avec Les boîtes de dialogues intégrées Excel ;
- avec Les boîtes de dialogues intégrées Access (à partir de 2007) ;
- ou avec des API si la version utilisée n'a pas de boîtes de dialogue intégrées : API GetOpenFileName.

On commence par écrire l'en-tête des données :

sFormDataHeader = "--" & csBoundary & vbCrLf & _
       "Content-Disposition: form-data; name=""fichier1"";filename=""" & sFileName & """" & vbCrLf & _
       "Content-Type: application/octet-stream" & vbCrLf & _
       vbCrLf

Comme nous allons envoyer un tableau d'octets, il ne faut pas qu'il soit au format Unicode (format des chaînes de caractères VB).
On doit donc ajouter une conversion :

sFormDataHeader = StrConv(sFormDataHeader, vbFromUnicode)

Puis on écrit de la même manière la fin des données (ce qu'il y a après le contenu du fichier) :

sFormDataFooter = vbCrLf & _
       "--" & csBoundary & "--"
sFormDataFooter = StrConv(sFormDataFooter, vbFromUnicode)

Occupons-nous maintenant des données du fichier.
Nous chargeons le fichier dans un tableau d'octets avec les fonctions de fichier VBA :

' Retourne le contenu brut d'un fichier (tableau d'octets)
Function GetFileBinary(FileName) As Variant
   Dim buffer() As Byte
   Dim f As Integer
   f = FreeFile
   Open FileName For Binary As #f
   ReDim buffer(1 To LOF(f))
   Get #f, , buffer
   Close #f
   GetFileBinary = buffer
End Function

Cette fonction peut être placée dans le module du formulaire ou dans un module séparé.

On ouvre le fichier avec For Binary pour préciser qu'on va lire le contenu brut et non pas un fichier texte séquentiel.
Le buffer est un tableau d'octets que l'on redimensionne à la taille du fichier avant de le remplir.
On place enfin ce buffer dans le retour de la fonction.

On peut alors ajouter l'écriture des données du fichier dans la variable sFormDataFile :

sFormDataFile = GetFileBinary(sFileName)

Pas de conversion à faire ici, on laisse les données brutes.

Pour finir la construction des données, on concatène le tout :

sFormData = sFormDataHeader & sFormDataFile & sFormDataFooter

La concaténation est possible entre des tableaux d'octets et des chaînes de caractères si les variables sont déclarées en Variant.

Voici la fonction complète :

Function SendFilePhp()
Dim oWinHTTP As WinHTTP.WinHttpRequest
Dim sFormData() As Byte
Dim sFormDataHeader As Variant
Dim sFormDataFile As Variant
Dim sFormDataFooter As Variant
Const csBoundary As String = "A@poXX125"
Const sFileName As String = "C:\monimage.jpg"
Set oWinHTTP = New WinHTTP.WinHttpRequest
oWinHTTP.Open "POST", "http://arkham46.developpez.com/articles/office/officeweb/fichiersphp/phpupload.php", False
oWinHTTP.setRequestHeader "Content-Type", "multipart/form-data; boundary=" + csBoundary
            
sFormDataHeader = "--" & csBoundary & vbCrLf & _
       "Content-Disposition: form-data; name=""fichier1"";filename=""" & sFileName & """" & vbCrLf & _
       "Content-Type: application/octet-stream" & vbCrLf & _
       vbCrLf
sFormDataHeader = StrConv(sFormDataHeader, vbFromUnicode)
sFormDataFooter = vbCrLf & _
       "--" & csBoundary & "--"
sFormDataFooter = StrConv(sFormDataFooter, vbFromUnicode)
sFormDataFile = GetFileBinary(sFileName)
            
sFormData = sFormDataHeader & sFormDataFile & sFormDataFooter
oWinHTTP.send sFormData
Debug.Print oWinHTTP.responseText
End Function
            
' Retourne le contenu brut d'un fichier (tableau d'octets)
Function GetFileBinary(FileName) As Variant
   Dim buffer() As Byte
   Dim f As Integer
   f = FreeFile
   Open FileName For Binary As #f
   ReDim buffer(1 To LOF(f))
   Get #f, , buffer
   Close #f
   GetFileBinary = buffer
End Function

Lorsqu'on l'exécute on récupère ceci dans la fenêtre Exécution :

Array
(
[fichier1] => Array
(
[name] => monimage.jpg
[type] => application/octet-stream
[tmp_name] => /tmp/phplXJMz2
[error] => 0
[size] => 7127
)

)

C'est le contenu de la variable $_FILES renvoyé par le php.

On voit que c'est un tableau (cf. le premier Array) qui contient un fichier ([fichier1]).
Les propriétés de ce fichier sont elles aussi dans un tableau dans lequel on trouve :
- name : le nom du fichier : notez que le chemin n'est pas inclus ;
- type : le type du fichier : c'est ce qu'on a mis dans content-type ;
- tmp_name : le nom temporaire du fichier téléchargé : nous allons nous y intéresser de près ;
- error : un éventuel code d'erreur ;
- size : la taille du fichier.

Le nom temporaire du fichier est très important.
En fait le fichier est uploadé dans un répertoire particulier.
Ce fichier est temporaire, il faut le déplacer ensuite à son emplacement final (sinon il sera détruit).

Pour déplacer un tel fichier, il faut utiliser la fonction php move_uploaded_file :

<?php print_r($_FILES); ?>
<?php 
if (move_uploaded_file($_FILES['fichier1']['tmp_name'], $_FILES['fichier1']['name']))
    { echo "Le fichier ". $_FILES['fichier1']['name']. " a été uploadé"; }
else
    { echo "Erreur lors de l'upload"; } 
            
?>

Ici on déplace le fichier 'fichier1' à partir de son emplacement temporaire.
On le déplace dans le même répertoire que le script php.

L'exécution de la fonction SendFilePhp retourne ceci :

Array
(
[fichier1] => Array
(
[name] => monimage.jpg
[type] => application/octet-stream
[tmp_name] => /tmp/phpoXPnTg
[error] => 0
[size] => 7127
)

)
Le fichier monimage.jpg a été uploadé

Le fichier a donc été chargé sur le serveur.

N'oubliez pas de mettre en place des vérifications de sécurité sur le fichier uploadé pour ne pas permettre à chacun d'envoyer n'importe quoi sur votre serveur.
Rapprochez-vous si nécessaire d'un expert php qui saura mieux que moi vous aider sur ce sujet.

Nous savons maintenant envoyer et recevoir des données à l'aide de php.
Pour exploiter ces données, on peut envisager de les stocker dans une base de données MySQL par exemple.
Vous trouverez de la documentation sur le sujet dans les cours mysql pour php.

PHP est également capable d'écrire des fichiers sur le serveur pour stocker les données.
Voici quelques fonctions basiques de gestion de fichiers pour lesquelles vous pouvez facilement trouver de la documentation : fopen, fputs, fclose.

Retrouvez tous les cours php