VBA et développement Web

Le navigateur se présente en VBA comme un objet de type InternetExplorer.
Cet objet représente un navigateur internet tel qu'il se présente lorsqu'on exécute Internet Explorer.

Pour disposer dans VBA des instructions nécessaires, il faut d'abord ajouter la librairie Microsoft Internet Controls.

Ensuite créez dans l'éditeur VBA un nouveau module de code : Insertion => Module.

Avant de créer le module, je vous conseille de modifier l'option de déclaration des variables :
- dans le menu : Outils => Options... ;
- cochez la case Déclaration des variables obligatoire.

Cela a pour effet d'ajouter en en-tête de chaque nouveau module l'instruction Option Explicit.
Cette instruction impose la déclaration de toutes les variables utilisées dans le code.
En précisant le type exact de toutes nos variables, on évite des conversions inutiles de données.
De plus, sans cette option, il est fréquent de faire des erreurs d'étourderie difficiles à déceler (une faute de frappe dans un nom de variable par exemple).
Il est également possible d'écrire cette instruction Option Explicit manuellement.

Nous allons écrire une petite procédure :

Public Sub CreerNavigateur()
            
End Sub

Dans cette procédure, commençons par déclarer notre objet navigateur :

Dim oNav As SHDocVw.InternetExplorer

Il n'y parait pas, mais il y a déjà beaucoup à dire sur cette ligne de code.

D'abord vous noterez que notre variable oNav qui contient un objet est préfixée par la lettre o.
Ce n'est pas grand-chose mais il est souvent utile de voir en un coup d'œil sur un code assez complexe de quel type est une variable.
Je vous renvoie à ces deux articles pour plus de détails sur les conventions de nommage des variables :
Descriptif des conventions typographiques du code Visual Basic ;
Convention générale de codage pour la programmation.

Ensuite on sait que l'objet que l'on souhaite créer est défini dans la librairie SHDocVw (Microsoft Internet Controls).
Il suffit alors de taper un point après ce nom de librairie pour avoir la liste de toutes les classes de cette librairie.
On pourrait ne pas préfixer la classe InternetExplorer par sa librairie SHDocVw.
Auquel cas VBA rechercherait dans toutes les références actives du projet une classe de nom InternetExplorer, au risque d'utiliser une classe d'une autre librairie.
À ma connaissance, InternetExplorer n'est pas défini dans une autre librairie qu'on utiliserait fréquemment, et donc le nom de librairie n'est pas ici indispensable.

Si vous n'êtes pas familier avec les variables objets, sachez qu'on a seulement déclaré notre variable oNav pour une utilisation future.
Elle n'est pour l'instant liée à aucun objet, le test oNav is Nothing renvoie Vrai.

Pour créer l'objet, il suffit d'utiliser le mot-clé New.

Set oNav = New SHDocVw.InternetExplorer

Il faut que le type qui suit New soit le même que celui utilisé pour déclarer la variable.

oNav pointe désormais vers un navigateur Internet Explorer.
À noter : ce navigateur est par défaut invisible !
Si vous exécutez le code tel quel, vous allez créer un navigateur qui restera ouvert. On ne pourra le fermer que dans le gestionnaire des tâches.

Garder le navigateur invisible peut être utile pour effectuer un traitement en arrière-plan.
Utilisez alors la méthode Quit de l'objet pour le fermer proprement.

Pour voir le navigateur, définissez sa propriété Visible.

oNav.Visible = True

Exécutez maintenant la procédure (F5 avec le curseur à l'intérieur de la procédure).
Une application Internet Explorer s'ouvre.

Par défaut, aucune page n'est ouverte.
Demandons la navigation vers une page : Google par exemple.
Il suffit d'utiliser la méthode Navigate de notre objet.

oNav.Navigate "http://google.fr"

Le navigateur tel que présenté dans le chapitre précédent s'ouvre dans une fenêtre distincte de l'application Office.
Il est également envisageable d'intégrer un navigateur dans un formulaire.
On parle alors de contrôle ActiveX WebBrowser (ou Navigateur Web).
Pour disposer dans VBA du contrôle et des instructions nécessaires, il faut d'abord ajouter la librairie Microsoft Internet Controls.

La méthode de création du contrôle est légèrement différente selon l'application et le type de formulaire.

III-B-1. Intégrer un navigateur internet à un formulaire Access▲

Private Sub Form_Open(Cancel As Integer)
   Me.ctlNav.Object.Navigate "http://google.fr"
End Sub

Dim oNav As SHDocVw.WebBrowser
Set oNav = Me.ctlNav.Object
oNav.Navigate "http://google.fr"

III-B-2. Intégrer un navigateur internet à un formulaire utilisateur (UserForm)▲

Me.ctlNav.Navigate "http://google.fr"

Les contrôles InternetExplorer et WebBrowser exposent des méthodes utiles à la navigation :
- Navigate pour naviguer vers une adresse ;
- GoBack pour naviguer vers la page précédente ;
- GoForward pour naviguer vers la page suivante ;
- GoHome pour naviguer vers la page d'accueil ;
- Refresh pour rafraîchir la page en cours.

Ces méthodes, associées à des boutons sur le formulaire, permettent une navigation minimale dans un WebBrowser sans avoir besoin du menu complet.
Elles sont également utilisables sur une application InternetExplorer.

Les navigateurs exposent différents événements.
Vous trouverez la documentation de ces événements sur MSDN (en anglais) : Reference for Visual BasicDevelopers.

III-D-1. Événements d'un contrôle WebBrowser▲

Private Sub ctlNav_DocumentComplete(ByVal pDisp As Object, URL As Variant)
End Sub

Private Sub ctlNav_DocumentComplete(ByVal pDisp As Object, URL As Variant)
   MsgBox "Document chargé" & vbCrLf & URL
End Sub

III-D-2. Événements d'un contrôle InternetExplorer▲

Private WithEvents oNav As SHDocVw.InternetExplorer
            
Private Sub btnNavigue_Click()
Set oNav = New SHDocVw.InternetExplorer
oNav.Visible = True
oNav.navigate "http://google.fr"
End Sub
            
Private Sub oNav_DocumentComplete(ByVal pDisp As Object, URL As Variant)
   MsgBox "Document chargé" & vbCrLf & URL
End Sub